Microsoft Web Browser - Come si usa?

[MarcoEli]

Ciao a tutti, ho provato ad inserire Microsoft Web Browser in un Form di Visual Basic ma non mi visualizza niente, qualcuno sa come funziona?

[Brothers]

Questo è il codice del form Browser (di nome frmBrowser)

----------------------------------------------------

Option Explicit

Public StartingAddress As String

Dim mbDontNavigateNow As Boolean

Private Sub Form_Load()

On Error Resume Next

Me.Show

tbToolBar.Refresh

Form_Resize

cboAddress.Move 50, lblAddress.Top + lblAddress.Height + 15

If Len(StartingAddress) > 0 Then

cboAddress.Text = StartingAddress

cboAddress.AddItem cboAddress.Text

'Tenta di passare all'indirizzo iniziale

timTimer.Enabled = True

brwWebBrowser.Navigate StartingAddress

End If

End Sub

Private Sub brwWebBrowser_DownloadComplete()

On Error Resume Next

Me.Caption = brwWebBrowser.LocationName

End Sub

Private Sub brwWebBrowser_NavigateComplete(ByVal URL As String)

Dim i As Integer

Dim bFound As Boolean

Me.Caption = brwWebBrowser.LocationName

For i = 0 To cboAddress.ListCount - 1

If cboAddress.List(i) = brwWebBrowser.LocationURL Then

bFound = True

Exit For

End If

Next i

mbDontNavigateNow = True

If bFound Then

cboAddress.RemoveItem i

End If

cboAddress.AddItem brwWebBrowser.LocationURL, 0

cboAddress.ListIndex = 0

mbDontNavigateNow = False

End Sub

Private Sub cboAddress_Click()

If mbDontNavigateNow Then Exit Sub

timTimer.Enabled = True

brwWebBrowser.Navigate cboAddress.Text

End Sub

Private Sub cboAddress_KeyPress(KeyAscii As Integer)

On Error Resume Next

If KeyAscii = vbKeyReturn Then

cboAddress_Click

End If

End Sub

Private Sub Form_Resize()

cboAddress.Width = Me.ScaleWidth - 100

brwWebBrowser.Width = Me.ScaleWidth - 100

brwWebBrowser.Height = Me.ScaleHeight - (picAddress.Top + picAddress.Height) - 100

End Sub

Private Sub timTimer_Timer()

If brwWebBrowser.Busy = False Then

timTimer.Enabled = False

Me.Caption = brwWebBrowser.LocationName

Else

Me.Caption = "Operazione in corso..."

End If

End Sub

Private Sub tbToolBar_ButtonClick(ByVal Button As Button)

On Error Resume Next

timTimer.Enabled = True

Select Case Button.Key

Case "Back"

brwWebBrowser.GoBack

Case "Forward"

brwWebBrowser.GoForward

Case "Refresh"

brwWebBrowser.Refresh

Case "Home"

brwWebBrowser.GoHome

Case "Search"

brwWebBrowser.GoSearch

Case "Stop"

timTimer.Enabled = False

brwWebBrowser.Stop

Me.Caption = brwWebBrowser.LocationName

End Select

End Sub

-----------------------------------------------------------------

-----------------------------------------------------------------

Ti Scrivo anche i componenti usati in questo codice

e Approssimativamente le proprietà di essi

poi se vorrai potrai modificarle da te:

------------------------------------------------------------------

Nome: brwWebBrowser Componente: WebBrowser

Nome: cboAddress Componente: ComboBox

Nome: imlIcons Componente: ImageList Proprieta: Contenga almeno 6 immagini (immagini nella ImageList che saranno le icone dei 6 Pulsanti)

Nome: lblAddress Componente: Label Proprieta: Tag e Caption &Indirizzo:

Nome: picAddress Componente: PictureBox Proprieta: LinkTimeout 50

Nome: timTimer Componente: Timer Proprieta: Interval 5

Nome: tbToolBar Componente: Toolbar Proprieta: Contenga almeno 6 Pulsanti

Pulsanti dentro alla tbToolBar per:

1° indietro 2° Avanti 3° ferma 4° Aggiorna 5° Home 6° Cerca

-----------------------------------------

Questo è il codice che devi mettere dentro ad un pulsante che ti avvia il frmBrowser

(io il Browser lo ho messo come form MDChild dentro un form Main , nel codice è già impostato il resize)

-----------------------------------------

Dim frmB As New frmBrowser

frmB.StartingAddress = "http://astalavista.box.sk/cgi-bin/robot"

frmB.Show

-----------------------------------------

Io ho messo la pagina di ricerca di Astalavista come avvio tu mettu quella che vuoi

Prova e in bocca al lupo

Ciao

Modificato: 29 luglio 2005 da Brothers

[Brothers]

Dimenticavo- occhio se usi questo indirizzo http://astalavista.box.sk/cgi-bin/robot

Fa comodo ma cercano sempre di attaccarti qualcosa.

Meglio se metti http://www.google.it/

Ciao

[MarcoEli]

Grazie mille, ci lavoro un pò su perche con .net non miaccetta tutti i parametri degli oggetti, appena finito ti faccio sapere come va...