Due WAN contemporaneamente su mikrotik

[abbio90]

Ciao a tutti...ho necessita di usare due wan contemporanee per aumentare la banda totale su piu appartamenti..

So che la banda delle due wan non si somma..ma come gestito il tutto?

Devo fare semplicemente due default route?

 

[abbio90]

Penso che questo faccia il caso mio..

Attendo il parere dei piu esperti

[abbio90]

Ho impostato cosi i mangle ma qualcosa non va..non navigo piu

Allego export dei mangle..

[abbio90]

Risolto

[thuke82]

Come hai risolto ?

[abbio90]

Stasera posto la configurazione completa nel caso possa tornare utile a qualcuno...

Ho aggiunto anche il fa il over oltre al balance pcc

Stasera posto la configurazione completa nel caso possa tornare utile a qualcuno...

Ho aggiunto anche il fa il over oltre al balance pcc

[abbio90]

# 2WAN BALANCE PCC

/interface bridge
add name=bridge_LAN

/interface wireless
set [ find default-name=wlan1 ] antenna-gain=6 band=2ghz-b/g/n channel-width=\
    20/40mhz-Ce country=italy disabled=no frequency-mode=regulatory-domain \
    installation=indoor mode=station-pseudobridge name=wlan1-ISP2 ssid=\
    ASUS_X008D wireless-protocol=802.11

/interface ethernet
set [ find default-name=ether1 ] name=ether1-ISP1

 

/interface wireless security-profiles
set [ find default=yes ] authentication-types=wpa-psk,wpa2-psk eap-methods="" \
    mode=dynamic-keys supplicant-identity=MikroTik wpa-pre-shared-key=\
    12345678 wpa2-pre-shared-key=12345678

/ip pool
add name="pool dhcp" ranges=192.168.1.199-192.168.1.243

/ip dhcp-server
add address-pool="pool dhcp" disabled=no interface=bridge_LAN name=\
    "dhcp server"

/interface bridge port
add bridge=bridge_LAN interface=ether2
add bridge=bridge_LAN interface=ether3
add bridge=bridge_LAN interface=ether4

/ip address
add address=10.246.159.60/24 interface=ether1-ISP1 network=10.246.159.0
add address=192.168.43.2/24 interface=wlan1-ISP2 network=192.168.43.0
add address=192.168.1.1/24 interface=bridge_LAN network=192.168.1.0

/ip dhcp-server network
add address=192.168.1.0/24 dns-server=192.168.1.1 gateway=192.168.1.1 \
    netmask=24

/ip dns
set allow-remote-requests=yes servers=1.1.1.1,1.0.0.1

/ip firewall mangle
add action=accept chain=prerouting dst-address=192.168.43.0/24 in-interface=\
    bridge_LAN
add action=accept chain=prerouting dst-address=10.246.159.0/24 in-interface=\
    bridge_LAN
add action=mark-connection chain=prerouting connection-mark=no-mark \
    in-interface=ether1-ISP1 new-connection-mark=ISP1_conn passthrough=yes
add action=mark-connection chain=prerouting connection-mark=no-mark \
    in-interface=wlan1-ISP2 new-connection-mark=ISP2_conn passthrough=yes
add action=mark-connection chain=prerouting comment="bilance pcc" \
    connection-mark=no-mark dst-address-type=!local in-interface=bridge_LAN \
    new-connection-mark=ISP1_conn passthrough=yes per-connection-classifier=\
    both-addresses:2/0
add action=mark-connection chain=prerouting connection-mark=no-mark \
    dst-address-type=!local in-interface=bridge_LAN new-connection-mark=\
    ISP2_conn passthrough=yes per-connection-classifier=both-addresses:2/1
add action=mark-routing chain=prerouting connection-mark=ISP1_conn \
    in-interface=bridge_LAN new-routing-mark=to_ISP1 passthrough=yes
add action=mark-routing chain=prerouting connection-mark=ISP2_conn \
    in-interface=bridge_LAN new-routing-mark=to_ISP2 passthrough=yes
add action=mark-routing chain=output connection-mark=ISP1_conn \
    new-routing-mark=to_ISP1 passthrough=yes
add action=mark-routing chain=output connection-mark=ISP2_conn \
    new-routing-mark=to_ISP2 passthrough=yes

/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether1-ISP1
add action=masquerade chain=srcnat out-interface=wlan1-ISP2

/ip route
add check-gateway=ping comment=ISP1 distance=1 gateway=8.8.8.8 routing-mark=\
    to_ISP1 target-scope=30
add check-gateway=ping comment=ISP2 distance=1 gateway=8.8.4.4 routing-mark=\
    to_ISP2 target-scope=30
add check-gateway=ping comment=ISP1 distance=1 gateway=8.8.8.8 target-scope=\
    30
add comment=ISP2 distance=2 gateway=8.8.4.4 target-scope=30
add distance=1 dst-address=8.8.4.4/32 gateway=192.168.43.1
add distance=1 dst-address=8.8.8.8/32 gateway=10.246.159.50

/system clock
set time-zone-name=Europe/Rome