Wave Von Vb6

[trentaluca]

Ciao ragazzi ..un informazione.....

Ho bisogno che un evento mi carichi un suono wave presente nell'hard disk..mi date una dritta??

[dago_]

Prova cosi:

'Inserisci nel tuo progetto un Modulo.bas e incolla

'questa dichiarazione (libreria Win Multimedia)

'Esistono altri sistemi, questo e' uno.Dovrebbe funzionare anche

'con con XP/2000 ma al momento non ho modo di provare.

Declare Function sndPlaySound Lib "winmm" Alias "sndPlaySoundA" _

    (ByVal lpszSoundName As String, ByVal uFlags As Long) As Long

'Incolla questa parte di codice nella sub form load o associala all'evento

'che ti interessa.

Private Sub Form_Load()

Dim Suono1 As Long

    Suono1 = sndPlaySound("c:\windows\media\ding.wav", 1)

End Sub

[trentaluca]

Non mi riconosce la funzione sndPlaySound..........comunque grazie....io ho dovuto fare così....

Dim dx As New DirectX8

Dim DS As DirectSound8

Dim suono As DirectSoundSecondaryBuffer8

Private Sub Form_Load()

creaSuono Form1.hWnd

Set suono = caricaWave(App.Path & "\chimes.wav")

End Sub

Sub creaSuono(Fhwnd As Long)

'crea il suono

Set DS = dx.DirectSoundCreate(vbNullString)

DS.SetCooperativeLevel Fhwnd, DSSCL_PRIORITY

End Sub

Function caricaWave(filesrc As String) As DirectSoundSecondaryBuffer8

Dim DSbuf As DSBUFFERDESC

DSbuf.lFlags = DSBCAPS_CTRLFREQUENCY Or DSBCAPS_CTRLPAN Or DSBCAPS_CTRLVOLUME Or DSBCAPS_LOCSOFTWARE

Set caricaWave = DS.CreateSoundBufferFromFile(filesrc, DSbuf)

End Function

Private Sub Form_Unload(Cancel As Integer)

Set DS = Nothing

End Sub

Private Sub TastoLoop_Click()

suono.PLAY DSBPLAY_LOOPING

End Sub

Private Sub PLAY()

suono.PLAY DSBPLAY_DEFAULT

End Sub

Private Sub TastoStop_Click()

suono.Stop

End Sub

NON MI SAPETE DIRE UN MODO PIù SEMLICE???

grazie

[trentaluca]

Scusa dago ..hai ragione.....funziona benissimo.........

Mi ero dimenticato di fare il modulo...

Ciao e grazie....

[dago_]